Backup der Registryeinträge mittels Batchdatei

Nicht immer geht alles glatt, manchmal braucht es halt ein Backup, auch von den Registryeinträgen. 

Diese können automatisiert mit der folgenden Batchdatei gesichert werden: 

REM Backup of the most important Registrykeys for Vpin-Software as File export
REM all keys are from the User-hive HKCU, they are valid for the just loggedin user
@echo off

REM system language independent use of date/time
for /f %%x in ('wmic path win32_localtime get /format:list ^| findstr "="') do set %%x
REM Format that leading "0" will be added, if necessary
if "%Month:~1,1%"=="" set Month=0%Month%
if "%Day:~1,1%"=="" set Day=0%Day%
if "%Hour:~1,1%"=="" set Hour=0%Hour%
if "%Minute:~1,1%"=="" set Minute=0%Minute%
if "%Second:~1,1%"=="" set Second=0%Second%

REM build date and time-string: YYYY-MM-DD_HH-MM-SS
set MYDATE=%Year%.%Month%.%Day%
set MYTIME=%Hour%-%Minute%-%Second%
set DateTime=%MYDATE%_%MYTIME%

REM every time a new directory is created for the exported keys and log files
mkdir %DateTime%

start /wait reg export HKCU\SOFTWARE\DirectOutput %DateTime%\DirectOutput.reg /Y
start /wait reg export HKCU\SOFTWARE\DOFLinx %DateTime%\DOFLinx.reg /Y
start /wait reg export "HKCU\SOFTWARE\Future Pinball" %DateTime%\FuturePinball.reg /y
start /wait reg export HKCU\SOFTWARE\Freeware %DateTime%\VPinMAME.reg /y
start /wait reg export HKCU\SOFTWARE\PinUPPopper %DateTime%\PinUPPopper.reg /y
start /wait reg export HKCU\SOFTWARE\UltraDMD %DateTime%\UltraDMD.reg /y
start /wait reg export HKCU\SOFTWARE\Valve %DateTime%\Steam.reg /y
start /wait reg export "HKCU\SOFTWARE\Visual Pinball" %DateTime%\VisualPinball.reg /y

REM save VPinballX.ini
copy %APPDATA%\VPinballX\VPinballX.ini %DateTime%\VPinballX.ini

Das Script wurde vom Benutzer Moster im Flippermarkt zur Verfügung gestellt